InputQuery / Inputbox com campo estilo senha

Hoje eu precisei pedir uma senha para o usuário do sistema, só que eu não queria criar um form só para solicitar a senha, dai eu resolvi usar InputQuery.
Só que havia um problema, o usuário não pode visualizar a senha enquanto digita. Então como fazer com que o InputQuery fique com o passwordChar igual a #?

O delphi não possui um componente/função que faça isso. Então eu fui ao bendito google e achei a função/procedimento que queria no Blog do Adriano Santos http://delphitodelphi.blogspot.com que além de escrever para o blog pessoal, cria alguns artigos para a revista ClubeDelphi da devMedia www.devmedia.com.br.

Para a função, você precisa adicionar na Uses, as seguintes unidades: Types, Controls e Windows.

Segue abaixo a função:

function InputQuerySenha(const ACaption, APrompt: string; var Value: string):
Boolean;
var
Form: TForm;
Prompt: TLabel;
Edit: TEdit;
DialogUnits: TPoint;
ButtonTop, ButtonWidth, ButtonHeight: Integer;
function GetAveCharSize(Canvas: TCanvas): TPoint;
var
I: Integer;
Buffer: array[0..51] of Char;
begin
for I := 0 to 25 do
  Buffer[I] := Chr(I + Ord('A'));
for I := 0 to 25 do
  Buffer[I + 26] := Chr(I + Ord('a'));
GetTextExtentPoint(Canvas.Handle, Buffer, 52, TSize(Result));
Result.X := Result.X div 52;
end;
procedure Saida(Sender: TObject);
begin
if TEdit(Sender).Text = '' then
begin
  ShowMessage('Vazio');
  TEdit(Sender).SetFocus;
end;
end;
begin
Result := False;
Form := TForm.Create(Application);
with Form do
try
Canvas.Font := Font;
DialogUnits := GetAveCharSize(Canvas);
BorderStyle := bsDialog;
Caption := ACaption;
ClientWidth := MulDiv(180, DialogUnits.X, 4);
Position := poScreenCenter;
Prompt := TLabel.Create(Form);
with Prompt do
begin
  Parent := Form;
  Caption := APrompt;
  Left := MulDiv(8, DialogUnits.X, 4);
  Top := MulDiv(8, DialogUnits.Y, 8);
  Constraints.MaxWidth := MulDiv(164, DialogUnits.X, 4);
  WordWrap := True;
end;
Edit := TEdit.Create(Form);
with Edit do
begin
  {Usando a fonte Wingdings e a letra "ele" em minúsculo, simula-se as "bolinhas" no lugar
       de asterísco da senha}
  Font.Name := 'Wingdings';
  PasswordChar := 'l';
  Parent := Form;
  Left := Prompt.Left;
  Top := Prompt.Top + Prompt.Height + 5;
  Width := MulDiv(164, DialogUnits.X, 4);
  MaxLength := 255;
  Text := Value;
  SelectAll;
end;
ButtonTop := Edit.Top + Edit.Height + 15;
ButtonWidth := MulDiv(50, DialogUnits.X, 4);
ButtonHeight := MulDiv(14, DialogUnits.Y, 8);
with TButton.Create(Form) do
begin
  Parent := Form;
  Caption := 'Confirmar';
  ModalResult := mrOk;
  Default := True;
  SetBounds(MulDiv(38, DialogUnits.X, 4), ButtonTop, ButtonWidth,
    ButtonHeight);
end;
with TButton.Create(Form) do
begin
  Parent := Form;
  Caption := 'Cancelar';
  ModalResult := mrCancel;
  Cancel := True;
  SetBounds(MulDiv(92, DialogUnits.X, 4), Edit.Top + Edit.Height + 15,
    ButtonWidth, ButtonHeight);
  Form.ClientHeight := Top + Height + 13;
end;
if ShowModal = mrOk then
begin
  Value := Edit.Text;
  Result := True;
end;
finally
Form.Free;
end;
end;

Exemplo de uso:

procedure TForm1.Button1Click(Sender: TObject);
var
Texto : string;
begin
InputQuerySenha('Caption', 'Caption', Texto);
Edit1.Text := Texto;
end;

Abraços pessoal. T+